<!--#include file="Include/conn.asp"-->
<!--#include file="Include/Fun_SqlIn.Asp"-->
<!DOCTYPE html PUBLIC "-//W3C//DTD XHTML 1.0 Transitional//EN" "http://www.w3.org/TR/xhtml1/DTD/xhtml1-transitional.dtd">
<html xmlns="http://www.w3.org/1999/xhtml">
<head>
<meta http-equiv="Content-Type" content="text/html; charset=GB2312" />
<meta http-equiv="Content-Language" content="zh-CN" />
<title>咨询中心 - <%=SiteTitle%></title>
<meta name="keywords" content="<%=Sitekeywords%>" />
<meta name="description" content="<%=Sitedescription%>" />
<link href="images/vote.css" rel="stylesheet" type="text/css" />
<script language="javascript" src="Images/webrui.js"></script>
</head>
<body>
<!--#include file="Include/head.asp"-->
<table width="999" border="0" cellspacing="0" cellpadding="0" class="main_class"  bgcolor="#FFFFFF"  align="center">
    <tr>
      <td valign="top" class="MainVote">
	  <table width="100%" border="0" cellspacing="0" cellpadding="0">
        <tr >
          <td width="517" align="left" style='line-height:30px;border-bottom:1px solid #FD380B;'><a href="../index.asp">首页</a><img src="Images/Arrow_02.gif" width="13" height="12" align="absmiddle"><a href='Book_List.asp'>咨询反馈</a><a href='Info_list.asp'></a><span class="Location"><a href="../index.asp"></a><img src="Images/Arrow_02.gif" width="13" height="12" align="absmiddle" />查看咨询</span></td>
		  <td width="120" align="left" style='line-height:30px;border-bottom:1px solid #FD380B;'><a href="Book_List.asp">查看咨询</a>|<a href="Book_Write.asp">签写咨询</a></td>
        </tr>
      </table>
      <table width="100%" border="0" cellspacing="0" cellpadding="0">
        <tr>
          <td width="15"></td>
          <td></td>
          <td width="15"></td>
        </tr>
	  <tr>
		<td colspan="3" height="20"></td>
	  </tr>
        <tr>
          <td>&nbsp;</td>
          <td class="MainBottm"><%=ContentList()%></td>
          <td>&nbsp;</td>
        </tr>
        </table>	  
	  </td>
    </tr>
  </table>
<!--#include file="Include/bottom.asp"-->
</body>
</html>

<%
function ContentList()
  dim SortPath
      SortPath=request.QueryString("SortPath")
  dim idCount'记录总数
  dim pages'每页条数
      pages=8
  dim pagec'总页数
  dim page'页码
      page=clng(request("Page"))
  dim pagenc'每页显示的分页页码数量=pagenc*2+1
      pagenc=2
  dim pagenmax'每页显示的分页的最大页码
  dim pagenmin'每页显示的分页的最小页码
  dim datafrom'数据表名
      datafrom="Web_rui_v_Message"
  dim datawhere'数据条件
		 datawhere="where ViewFlag=1 "
  dim sqlid'本页需要用到的id
  dim Myself,PATH_INFO,QUERY_STRING'本页地址和参数
      PATH_INFO = request.servervariables("PATH_INFO")
	  QUERY_STRING = request.ServerVariables("QUERY_STRING")'
      if QUERY_STRING = "" then
	    Myself = PATH_INFO & "?"
	  elseif Instr(PATH_INFO & "?" & QUERY_STRING,"Page=")=0 then
	    Myself= PATH_INFO & "?" & QUERY_STRING & "&"
	  else
	    Myself = Left(PATH_INFO & "?" & QUERY_STRING,Instr(PATH_INFO & "?" & QUERY_STRING,"Page=")-1)
	  end if
  dim taxis'排序的语句 asc,desc
      taxis="order by id   "
  dim i'用于循环的整数
  dim rs,sql'sql语句
  '获取记录总数
  sql="select count(ID) as idCount from ["& datafrom &"]" & datawhere
  set rs=server.createobject("adodb.recordset")
  rs.open sql,conn,0,1
  idCount=rs("idCount")
  '获取记录总数

  if(idcount>0) then'如果记录总数=0,则不处理
    if(idcount mod pages=0)then'如果记录总数除以每页条数有余数,则=记录总数/每页条数+1
	  pagec=int(idcount/pages)'获取总页数
   	else
      pagec=int(idcount/pages)+1'获取总页数
    end if
	'获取本页需要用到的id============================================
    '读取所有记录的id数值,因为只有id所以速度很快
    sql="select id from ["& datafrom &"] " & datawhere & taxis
    set rs=server.createobject("adodb.recordset")
    rs.open sql,conn,1,1
    rs.pagesize = pages '每页显示记录数
    if page < 1 then page = 1
    if page > pagec then page = pagec
    if pagec > 0 then rs.absolutepage = page  
    for i=1 to rs.pagesize
	  if rs.eof then exit for  
	  if(i=1)then
	    sqlid=rs("id")
	  else
	    sqlid=sqlid &","&rs("id")
	  end if
	  rs.movenext
    next
  '获取本页需要用到的id结束============================================
  end if
  Response.Write "<table width='100%' border='0' cellspacing='0' cellpadding='0'>"
  if(idcount>0 and sqlid<>"") then'如果记录总数=0,则不处理
    '用in刷选本页所语言的数据,仅读取本页所需的数据,所以速度快
    sql="select * from ["& datafrom &"] where id in("& sqlid &") "&taxis
    set rs=server.createobject("adodb.recordset")
    rs.open sql,conn,0,1
    while not rs.eof '填充数据到表格
	  Response.Write "<tr>" & vbCrLf
      Response.Write "<td width='100%' valign='top'>"
	  response.write "<DIV class=reply>"
	  response.write "<DIV class=inner><SPAN class=author><SPAN class=from>"
	  response.write "【"&rs("Linkman")&"】 留言："
	  response.write "</SPAN><DIV style='DISPLAY: none'><SPAN class=ip>"
	  response.write "</SPAN></DIV></SPAN><SPAN class=postTime>"
	  response.write ""&FormatDate(rs("AddTime"),1)&"  发表"
	  response.write "</SPAN><DIV class=body><DIV>"&rs("Content")&"</DIV></DIV></DIV></DIV>"  
      Response.Write "</td>" & vbCrLf
      Response.Write "</tr>" & vbCrLf
	  rs.movenext
    wend
  else
    response.write "<tr><td align='center'>暂无相关信息</td></tr></table>"
	exit function
  end if
  Response.Write "<tr>" & vbCrLf
  Response.Write "<td colspan='3' align='right'>" & vbCrLf
  Response.Write "共计：<font color='#ff6600'>"&idcount&"</font>条记录&nbsp;页次：<font color='#ff6600'>"&page&"</font></strong>/"&pagec&"&nbsp;每页：<font color='#ff6600'>"&pages&"</font>条&nbsp;&nbsp;&nbsp;&nbsp;" & vbCrLf
  pagenmin=page-pagenc '计算页码开始值
  pagenmax=page+pagenc '计算页码结束值
  if(pagenmin<1) then pagenmin=1 '如果页码开始值小于1则=1
  if(page>1) then response.write ("<a href='"& myself &"Page=1'><font style='FONT-SIZE: 14px; FONT-FAMILY: Webdings'>9</font></a>&nbsp;") '如果页码大于1则显示(第一页)
  if(pagenmin>1) then response.write ("<a href='"& myself &"Page="& page-(pagenc*2+1) &"'><font style='FONT-SIZE: 14px; FONT-FAMILY: Webdings'>7</font></a>&nbsp;") '如果页码开始值大于1则显示(更前)
  if(pagenmax>pagec) then pagenmax=pagec '如果页码结束值大于总页数,则=总页数
  for i = pagenmin to pagenmax'循环输出页码
	if(i=page) then
	  response.write ("&nbsp;<font color='#ff6600'>"& i &"</font>&nbsp;")
	else
	  response.write ("[<a href="& myself &"Page="& i &">"& i &"</a>]")
	end if
  next
  if(pagenmax<pagec) then response.write ("&nbsp;<a href='"& myself &"Page="& page+(pagenc*2+1) &"'><font style='FONT-SIZE: 14px; FONT-FAMILY: Webdings'>8</font></a>&nbsp;") '如果页码结束值小于总页数则显示(更后)
  if(page<pagec) then response.write ("<a href='"& myself &"Page="& pagec &"'><font style='FONT-SIZE: 14px; FONT-FAMILY: Webdings'>:</font></a>") '如果页码小于总页数则显示(最后页)	
  Response.Write "</td>" & vbCrLf
  Response.Write "</tr>" & vbCrLf
  Response.Write "</table>" & vbCrLf
  rs.close
  set rs=nothing
end function 

%>
