<%

Function IsValidEmail(email)
dim names, name, i, c
IsValidEmail = true
names = Split(email, "@")
if UBound(names) <> 1 then
   IsValidEmail = false
   exit Function
end if
for each name in names
   if Len(name) <= 0 then
     IsValidEmail = false
     exit Function
   end if
   for i = 1 to Len(name)
     c = Lcase(Mid(name, i, 1))
     if InStr("abcdefghijklmnopqrstuvwxyz_-.", c) <= 0 and not IsNumeric(c) then
       IsValidEmail = false
       exit Function
     end if
   next
   if Left(name, 1) = "." or Right(name, 1) = "." then
      IsValidEmail = false
      exit Function
   end if
next
if InStr(names(1), ".") <= 0 then
   IsValidEmail = false
   exit Function
end if
i = Len(names(1)) - InStrRev(names(1), ".")
if i <> 2 and i <> 3 then
   IsValidEmail = false
   exit Function
end if
if InStr(email, "..") > 0 then
   IsValidEmail = false
end if
end Function

%>