 <%@LANGUAGE="VBSCRIPT" CODEPAGE="936"%>
<!--#include file="conn.asp"-->
<!--#include file="Ex_Cls/Ex_SkinCls.asp"-->
<!--#include file="Ex_Cls/Ex_RefreshCls.asp"-->
<!--#include file="Ex_Cls/Ex_SplitPageCls.asp"-->
<%
Dim ExComm
Set ExComm=new Ex_CommonCls
ExComm.GetConfigCache("runmode,ShowName,CmtPageSize,IsCheckCode,cmtmsgcheckre,iscmtmsgcheck,LogNum,blogname,BlogDescription,BlogKeyWord,IndexAddWord,blogurl,logourl,DefaultSkin,CopyRight")
ExComm.CheckInstall
ExComm.IsIpAllow
Dim Title,Show_logids,show_blogKeyword
'******************************************
'生成日志上一篇 下一篇代码
'id--当前日志的id
'******************************************
Function proNext(id)
dim rs,strsql,ExNow
ExNow=ExComm.ExNow()
set rs=server.CreateObject("adodb.recordset")
strsql="select top 1 id,title,classid,ishide from Ex_log where id>"&id&" and textnum<>0 and datediff('d','"&ExNow&"',submittime)<=0 order by submittime asc"
rs.open strsql,Conn,1,1
if not rs.eof and not rs.bof Then
	If Application(sn&"runmode")<>"动态" And rs("ishide")="游客" Then 
		proNext="上一篇:&nbsp;"&"<a href="""&ExComm.CreateUrl(ExComm.GetClassFolder(Rs("classid")),ExComm.GetLogName(Rs("id")),"")&""">"&rs("title")&"</a>&nbsp;&nbsp;<br>"
	Else
		proNext="上一篇:&nbsp;"&"<a href=""blogview.asp?id="&rs("id")&""">"&rs("title")&"</a>&nbsp;&nbsp;<br>"	
	End if
end if
rs.close
strsql="select top 1 id,classid,title,ishide,textnum,logpass from Ex_log where id<"&id&" and textnum<>0 and datediff('d','"&ExNow&"',submittime)<=0 order by submittime desc"
rs.open strsql,Conn,1,1
if not rs.eof and not rs.bof Then
	If Application(sn&"runmode")<>"动态" And Rs("ishide")="游客" And Rs("textnum")<>0  And (Trim(Rs("logpass"))="" Or IsNull(Rs("logpass"))) Then
		proNext=proNext&"下一篇:&nbsp;"&"<a href="""&ExComm.CreateUrl(ExComm.GetClassFolder(Rs("classid")),ExComm.GetLogName(Rs("id")),"")&""">"&rs("title")&"</a>&nbsp;&nbsp;<br>"
	Else
		proNext=proNext&"下一篇:&nbsp;"&"<a href=""blogview.asp?id="&rs("id")&""">"&rs("title")&"</a>&nbsp;&nbsp;<br>"
	End If 
end if
rs.close
set rs=nothing
end function
'******************************************
'显示日志内容
'******************************************
Function Show_LogMore(ExSkin)
Dim id,sql,rs
Dim show_logtext,show_topic,show_loginfo,show_more,show_logcyc,iscmt,show_copyright,show_author,show_addtime
Dim show_topictxt,show_emot,show_logcls,show_topicurl,logName,BlogViewUrl
Dim Skin2
id=clng(request.querystring("id"))
Show_logids=id
sql="select * from Ex_log where id="&id
Set rs=Conn.execute(sql)
if not rs.eof And  not rs.bof Then
logName=rs("title")
iscmt=rs("iscmt")
'构造$show_topic$
If Application(sn&"runmode")="静态" Then
	BlogViewUrl=ExComm.CreateUrl(ExComm.GetClassFolder(Rs("classid")),ExComm.GetLogName(Rs("id")),"")
	show_topic="<a href=index.asp?classid="&rs("classid")&">["&ExComm.GetClassName(rs("classid"))&"]</a>"
	show_logcls=Replace(show_topic,"[","")
	show_logcls=Replace(show_logcls,"]","")
	If Rs("ishide")="游客" And Rs("textnum")<>0  And (Trim(Rs("logpass"))="" Or IsNull(Rs("logpass"))) Then 
		show_topic=show_topic&"<a href="&BlogViewUrl&" >"&rs("title")&"</a>"
		show_topicurl=BlogViewUrl
	Else
		show_topic=show_topic&"<a href=blogview.asp?id="&rs("id")&">"&rs("title")&"</a>"
		show_topicurl="blogview.asp?id="&rs("id")
	End If 
Else
	show_topic="<a href=index.asp?classid="&rs("classid")&">["&ExComm.GetClassName(rs("classid"))&"]</a>"
	show_logcls=Replace(show_topic,"[","")
	show_logcls=Replace(show_logcls,"]","")
	show_topic=show_topic&"<a href=blogview.asp?id="&rs("id")&">"&rs("title")&"</a>"
	show_topicurl="blogview.asp?id="&rs("id")
End if      
'构造$show_loginfo$
show_loginfo=""&Application(sn&"ShowName")&" 发表于 "&rs("log_postyear")&"-"&rs("log_postmonth")&"-"&rs("log_postday")&" "&Hour(Rs("submittime"))&":"&Minute(Rs("submittime"))&":"&Second(Rs("submittime"))
'构造$show_logtext$
If ExComm.IsLogin("admin")=False  And rs("ishide")="隐藏" then
	show_logtext="<div align=center>此处隐藏一篇日志。</div>"
elseif rs("logpass")<>"" And  ExComm.IsLogin("admin")=False And request("checkpass")<>rs("logpass") then
	show_logtext="<div align=center>此日志需要密码访问<br><FORM METHOD=POST ACTION=""blogview.asp?id="&rs("id")&"&check=true""><INPUT TYPE=""text"" NAME=""checkpass"" id=""checkpass""><INPUT TYPE=""submit"" value=""查看""></FORM></div>"
ElseIf  ExComm.IsLogin("admin")=False And rs("ishide")="会员" And ExComm.IsLogin("user")=False Then
	show_logtext="<div align=center><br>本日志只有会员才可以查看,如果您是会员请登陆</div>"
Else
	Dim tags,tags_start,tags_end,tags_str
	tags=rs("tags")
	show_blogKeyword=Replace(tags&" "," ",",")
	If tags<>"" then
		tags=Split(tags," ")
		tags_end=UBound(tags)
		For tags_start=0 To tags_end
			tags_str= tags_str&"<a href=index.asp?action=search&selecttype=tags&keyword="&server.urlencode(tags(tags_start))&"&classid="&rs("classid")&">"&tags(tags_start)&"</a>&nbsp;"
		Next
	End if
	show_logtext=rs("content")
	show_logtext=show_logText&"<br>日志标签："&tags_str
	show_logtext=show_logText&"<br>"&proNext(rs("id"))
end If
'构造$show_copyright$
If Rs("copyright")=True Then 
	show_CopyRight=Application(Sn&"CopyRight")
Else
	show_CopyRight=""
End If 
'构造$show_more$ 此标记为js调用显示
show_more=ExSkin.More(Rs("Id"))
'构造$show_emot$
show_emot="<img src=images/emotion/em0"&rs("emotion")&".gif >"
'构造$show_author$
show_author=Application(sn&"showname")
'构造$show_addtime$
show_addtime=rs("log_postyear")&"-"&rs("log_postmonth")&"-"&rs("log_postday")&" "&Hour(Rs("submittime"))&":"&Minute(Rs("submittime"))&":"&Second(Rs("submittime"))
'构造$show_topictxt$
show_topictxt=rs("title")
Title=show_topictxt
'辅模板替换开始
Skin2=ExSkin.GetTxtSkin("show_logmore.html")
show_logcyc=replace(Skin2,"$show_topic$",show_topic)
show_logcyc=replace(show_logcyc,"$show_loginfo$",show_loginfo)
show_logcyc=replace(show_logcyc,"$show_more$",show_more)
show_logcyc=replace(show_logcyc,"$show_emot$",show_emot)
show_logcyc=replace(show_logcyc,"$show_author$",show_author)
show_logcyc=replace(show_logcyc,"$show_addtime$",show_addtime)
show_logcyc=replace(show_logcyc,"$show_topictxt$",show_topictxt)
show_logcyc=replace(show_logcyc,"$show_logtext$",show_logtext)
show_logcyc=replace(show_logcyc,"$show_logcls$",show_logcls)
show_logcyc=replace(show_logcyc,"$show_topicurl$",show_topicurl)
show_logcyc=replace(show_logcyc,"$show_copyright$",show_copyright)
show_logmore=show_logmore&show_logcyc

'回复部分显示
Dim ExPages,page
	Set ExPages=new Ex_SplitPageCls
	Expages.letConn=Conn
	Expages.letColumns="select *"
	ExPages.letDataFrom="from Ex_Comment"
	ExPages.letOrder="order by id desc"
If ExComm.IsLogin("admin")=False Then 
	If ExComm.G(request.querystring("cmtid"))<>"" Then
		ExPages.letWhere="where isshow='是' and id="&CLng(request.querystring("cmtid"))
	Else
		ExPages.letWhere="where isshow='是' and parentid="&CLng(id)
	End If
Else 
	If ExComm.G(request.querystring("cmtid"))<>"" Then
		ExPages.letWhere="where id="&CLng(request.querystring("cmtid"))
	Else
		ExPages.letWhere="where parentid="&CLng(id)
	End If
End If 
Set Rs=server.CreateObject("adodb.recordset")
Expages.letPageSize=Application(sn&"CmtPageSize")
If ExComm.G(request("page"))="" Then
	page=1
Else
	page=CLng(request("page"))
End if
ExPages.letPage=page
ExPages.letStrPage="&id="&ExComm.G(request("id"))
ExPages.Execute()
Set Rs=ExPages.GetRs
If ExPages.GetRsCount<>0 then
	Do While Not rs.eof
		'构造$show_topic$
		show_topic=rs("cmttitle")
		'构造$show_loginfo$和'构造$show_author$
		if trim(rs("userhome"))<>"" and trim(rs("userhome"))<>"http://" then
			show_loginfo="<a href="""&rs("userhome")&""" target=""_blank"" title=""查看主页"">"&rs("username")&"</a>"&"于"&rs("addtime")&"发表"
			show_author="<a href="""&rs("userhome")&""" target=""_blank"" title=""查看主页"">"&rs("username")&"</a>"
		else
			show_loginfo=rs("username")&"于"&rs("addtime")&"发表"
			show_author=rs("username")
		end If
		'构造$show_logtext$
		show_logtext=rs("cmtcomment")
		'构造$show_more$
		Show_more=" "
		If ExComm.isLOGIN("user") And Rs("username")=session("user") then
			show_more="<a href=""?ac=edit&editid="&rs("id")&"&id="&id&"#cmtpost"">编辑</a>"
		End If
		If ExComm.IsLogin("admin") Then 
			show_more=show_more&" | <a href=""admin_Cmt.asp?action=del&id="&rs("id")&""" onclick=""return confirm('是否要删除？')"">删除</a>"
		End If 
		'构造$show_emot$
		show_emot=""
		'构造$show_addtime$
		show_addtime=rs("addtime")
		'构造$show_topictxt$
		show_topictxt=rs("cmttitle")
		If ExComm.IsOblogSkin Then 
			show_logcyc=Skin2
		Else 
			show_logcyc=ExSkin.GetTxtSkin("show_logcmt.html")
		End If 
		show_logcyc=replace(show_logcyc,"$show_topic$",show_topic)
		show_logcyc=replace(show_logcyc,"$show_loginfo$",show_loginfo)
		show_logcyc=replace(show_logcyc,"$show_logtext$",show_logtext)
		show_logcyc=replace(show_logcyc,"$show_more$",show_more)
		show_logcyc=replace(show_logcyc,"$show_emot$",show_emot)
		show_logcyc=replace(show_logcyc,"$show_author$",show_author)
		show_logcyc=replace(show_logcyc,"$show_addtime$",show_addtime)
		show_logcyc=replace(show_logcyc,"$show_topictxt$",show_topictxt)	
		show_logcyc=replace(show_logcyc,"$show_cmtid$",Rs("id"))
		rs.movenext
		show_logmore=show_logmore&"<a name=""#cmttop""></a>"&show_logcyc
	Loop
	dim showpage
	showpage=showpage&"<div align=center>"&ExPages.Show&"</div>"
	'分页结束
    show_logmore=show_logmore&showpage
	rs.close
	Set rs=Nothing
End If

'显示回复框
If iscmt="游客" or (iscmt="会员" and ExComm.IsLogin("user")) then
	show_logmore=show_logmore&"<a name=""#cmtpost""></a>  <div align=""center"">"
	show_logmore=show_logmore&"  <table border=""0"" width=""60%"" id=""Ex_cmttab"" align=""center"">"
	If request("ac")="edit" Then 
		show_logmore=show_logmore&"<form method=""POST"" action=""blogview.asp?action=edit&editid="&request("editid")&"&id="&id&""" id=""Ex_cmt"">"
	Else
		show_logmore=show_logmore&"<form method=""POST"" action=""blogview.asp?action=save&id="&id&""" id=""Ex_cmt"">"
	End if
	show_logmore=show_logmore&"    <tr>"
	show_logmore=show_logmore&"      <td width=""17%"">昵称:<font color=""red"">*</font></td>"
	show_logmore=show_logmore&"      <td width=""83%"" style=""text-align:left;""><input type=""text"" name=""username"" size=""20"" value="""&ExComm.UnDeCode(request.Cookies(Md5(sn))("uname"))&""" align=""left""></td>"
	show_logmore=show_logmore&"    </tr>"
	show_logmore=show_logmore&"    <tr>"
	show_logmore=show_logmore&"      <td width=""17%"">密码：</td>"
	show_logmore=show_logmore&"      <td width=""83%"" style=""text-align:left;""><input type=""password"" name=""userpass"" id=""password"" size=""20"" value="""&ExComm.UnDeCode(request.Cookies(Md5(sn))("upwd"))&"""><font color=red>&nbsp;&nbsp;[游客不必填写]</font></td>"
	show_logmore=show_logmore&"    </tr>"
	show_logmore=show_logmore&"    <tr>"
	show_logmore=show_logmore&"      <td width=""17%"">主页:</td>"
	show_logmore=show_logmore&"      <td width=""83%"" style=""text-align:left;""><input type=""text"" name=""homepage"" size=""20"" value="""&ExComm.UnDeCode(request.Cookies(Md5(sn))("homepage"))&"""></td>"
	show_logmore=show_logmore&"    </tr>"
	If Application(sn&"IsCheckCode")="是" Then 
	show_logmore=show_logmore&"    <tr>"
	show_logmore=show_logmore&"      <td width=""17%"">验证码：<font color=""red"">*</font></td>"
	show_logmore=show_logmore&"      <td width=""83%"" style=""text-align:left;""><input type=""text"" name=""checkcode"" id=""checkcode"" size=""10""><img src=""inc/checkcode.asp"" style=""cursor:hand"" onclick=""this.src='inc/checkcode.asp';"" alt=""看不清?点一下"" /></td>"
	show_logmore=show_logmore&"    </tr>"
	End If 
	If request("ac")<>"edit" then
		show_logmore=show_logmore&"    <tr style=""display:none"">"
		show_logmore=show_logmore&"      <td width=""17%"">标题：<font color=""red"">*</font></td>"
		show_logmore=show_logmore&"      <td width=""83%""><input type=""text"" name=""cmttitle"" size=""35"" value=""re:"&logName&"""></td></tr><tr><td colspan=""2"">"
		show_logmore=show_logmore&"<textarea name=""aBody"" id=""aBody""></textarea>"&vbcrlf
		show_logmore=show_logmore&"</tr></form>"
		show_logmore=show_logmore&"    <tr>"&vbcrlf
		show_logmore=show_logmore&"      <td width=""100%"" colspan=""2"">"
	Else
		Dim cc
		cc=Conn.execute("select cmttitle,cmtcomment from ex_comment where id="&CInt(request("editid")))
		show_logmore=show_logmore&" <tr style=""display:none;"">"
		show_logmore=show_logmore&"  <td width=""17%"">标题：<font color=""red"">*</font></td>"
		show_logmore=show_logmore&"  <td width=""83%""><input type=""text"" name=""cmttitle"" size=""35"" value="""&cc(0)&"""></td></tr><tr><td colspan=""2"">"
		show_logmore=show_logmore&"<textarea name=""aBody"" id=""aBody"" >"&server.htmlencode(cc(1))&"</textarea>"&vbcrlf
		show_logmore=show_logmore&"</tr></form>"
		show_logmore=show_logmore&"    <tr>"&vbcrlf
		show_logmore=show_logmore&" <td width=""100%"" colspan=""2"">"
	End If
	show_logmore=show_logmore&"<script>KE.show({id : 'aBody',items : ['undo', 'redo', 'fontname', 'fontsize', 'textcolor', 'bgcolor', 'bold', 'italic', 'underline','removeformat', 'justifyleft', 'justifycenter', 'justifyright', 'emoticons','insertorderedlist'],height : '150px', width:'420px'});</script>"
	show_logmore=show_logmore&"</td></tr>"
	show_logmore=show_logmore&"    <tr>"
	show_logmore=show_logmore&"      <td width=""100%"" colspan=""2""><input type=""submit"" value=""提交"" name=""B1"" onclick=""doSubmit()""></td>"
	show_logmore=show_logmore&"<script>"&vbcrlf&"function doSubmit(){document.getElementById(""aBody"").value=KE.util.getData('aBody');document.getElementById(""Ex_cmt"").submit()}"&vbcrlf&"</script>"
	show_logmore=show_logmore&"    </tr>"
	show_logmore=show_logmore&"  </table>"
	show_logmore=show_logmore&"  </div>"
	show_logmore=show_logmore&"<br>提示：代<font color=""red"">*</font>的和内容必须填写！！"
Else
	If iscmt="会员" then
		show_logmore=show_logmore&"<br><center>此文章只有会员才可以回复,如果您是会员请登陆</center>"
	Else
		show_logmore=show_logmore&"<br><center>此文章禁止回复</center>"
	End if
end If
Else
show_logmore="日志不存在！！！"
End if
End Function
'*****************************
'及时生成回复信息静态页
'参数:被回复信息id
'****************************
Function CreateCmt(id)
	Dim ExRefresh
	Set ExRefresh=new Ex_RefreshCls
	ExRefresh.CreateView id
End Function 
Dim logmore
If request.querystring("id")=""then
	If c_year="" Then c_year=Year(now)
	If c_month="" Then c_month=Month(now)
	If c_day="" Then c_day=Month(now)
	response.redirect("index.asp?c_year="&c_year&"&c_month="&c_month&"&c_day="&c_day)
End If

If request.querystring("action")="save" Then
    save
ElseIf request.querystring("action")="edit" Then 
	edit
End If

Sub save()
 Dim cmttitle,cmtcontent,username,userpass,userhome,checkcode,rs,parentid,strsql,cmtid,CmtSql
 Dim IsShow,Msg,ExSkin
 Dim ExNow
 ExNow=ExComm.ExNow()
 cmtid=CLng(request.querystring("id"))
 cmttitle=ExComm.F(request.Form("cmttitle"))
 username=ExComm.F(trim(request.Form("username")))
 userpass=ExComm.F(trim(request.Form("userpass")))
 userhome=ExComm.F(request.Form("homepage"))
 cmtcontent=ExComm.G(request.Form("aBody"))
 checkcode=ExComm.G(request.Form("checkcode"))
 if (session("excheckcode")<>checkcode Or Session("excheckcode")="") And Application(sn&"IsCheckCode")="是" then
	ExComm.ShowMsg "验证码不正确",""
 end If
 If Request.cookies(Application(Sn&"blogurl"))<>Sn And Application(sn&"IsCheckCode")="是" Then 
	ExComm.ShowMsg "你是机器人吧?",""
 End If 
 '身份验证开始
 If userpass<>"" Then 
	If ExComm.CheckUNP(username,userpass) Then 
		If Len(userpass)<=20 Then 
			response.Cookies(Md5(sn))("uname")=ExComm.DeCode(username)
			response.Cookies(Md5(sn))("upwd")=ExComm.DeCode(md5(userpass))
			response.Cookies(Md5(sn))("homepage")=ExComm.DeCode(userhome)
			session("user")=username
		End If 
	Else 
		ExComm.ShowMsg "帐号,密码不正确或您的帐号被锁定。",""
	End If 
 Else
	Rs=Conn.execute("select count(*) from Ex_user where username='"&username&"'")
	If Rs(0)<>0 Then 
		ExComm.ShowMsg "你使用的昵称已经被人注册，请更换其它昵称",""
	End If 
 End If
 '身份验证结束
 If cmttitle<>"" And username<>"" And cmtcontent<>"" Then
	If ExComm.CheckRe(ExComm.clearHtml(cmtcontent),Application(sn&"cmtmsgcheckre")) And Application(sn&"iscmtmsgcheck")="是" Then 
		IsShow="否"
		Msg="\年博客开启了评论审核功能,此信息需要审核才能显示."
	Else 
		IsShow="是"
		Msg=""
		Conn.execute("update Ex_log set cmt=cmt+1 where id="&cmtid)
	'缓存评论数量加一
	End If
	CmtSql="insert into Ex_Comment (cmttitle,username,cmtcomment,addtime,addip,parentid,userpass,userhome,isshow) values ('"&cmttitle&"','"&username&"','"&FilterCmt(cmtcontent)&"',#"&ExNow&"#,'"&ExComm.GetIp()&"',"&cmtid&",'"&userpass&"','"&checkhttp(userhome)&"','"&isShow&"')"
	Conn.Execute CmtSql
	Application.lock
	Application(sn&"cmttotal")=Application(sn&"cmttotal")+1
	Application.unlock
	'更新最新评论缓存
	Set ExSkin=new Ex_SkinCls
	ExSkin.RefreshSkinCache
	Set ExSkin=Nothing 
	CreateCmt cmtid
'	ExComm.ShowMsg "您已经成功发布了评论。"&Msg,request.servervariables("http_referer")
	ExComm.ShowMsg "您已经成功发布了评论。"&Msg,"/blogview.asp?id="&cmtid
 Else
	ExComm.ShowMsg "请填写完整",""
 End if
 End Sub

 Sub edit
		Dim cmttitle,cmtcontent,username,userpass,userhome,checkcode,strsql,ParentId,cmtid,CmtSql,CmtRs,IsShow,Msg
		Dim ExNow
		ExNow=ExComm.ExNow()
		ParentId=CLng(request.querystring("id"))
		cmtid=clng(request.querystring("editid"))
		cmttitle=ExComm.F(request.Form("cmttitle"))
		username=ExComm.F(trim(request.Form("username")))
		userpass=ExComm.F(trim(request.Form("userpass")))
		cmtcontent=ExComm.G(request.Form("aBody"))
		userhome=ExComm.F(request.Form("homepage"))
		checkcode=request.Form("checkcode")
		if (session("excheckcode")<>checkcode Or Session("excheckcode")="") And Application(sn&"IsCheckCode")="是" then
			ExComm.ShowMsg "验证码不正确",""
		end if
		If cmttitle<>"" And username<>"" And userpass<>"" And cmtcontent<>"" Then
			 CmtRs=Conn.execute("select count(*) from Ex_User where username='"&username&"' and userpwd='"&userpass&"'")
			If CmtRs(0)=0 Then 
				ExComm.ShowMsg "你的帐号或密码不正确",""
			End If
			If ExComm.CheckRe(ExComm.clearHtml(cmtcontent),Application(sn&"cmtmsgcheckre")) And Application(sn&"iscmtmsgcheck")="是" Then 
				IsShow="否"
				Msg="\n博客开启了评论审核功能,此信息需要审核才能显示."
				Conn.execute("update Ex_log set cmt=cmt-1 where id="&ParentId)
			'缓存评论数量加一
			Else 
				IsShow="是"
				Msg=""
			End If 
			CmtSql="update Ex_Comment set cmttitle='"&cmttitle&"',username='"&username&"',cmtcomment='"&FilterCmt(cmtcontent)&"',addtime=#"&ExNow&"#,addip='"&ExComm.GetIp()&"',userpass='"&userpass&"',userhome='"&checkhttp(userhome)&"',isshow='"&IsShow&"' where id="&cmtid&""
			Conn.Execute cmtSql
			CreateCmt(CLng(request.querystring("id")))
			response.write("<script>alert('您已经成功的修改评论."&Msg&"')</script>")
		Else
			ExComm.ShowMsg "请填写完整",""
		End If
 response.Write("<script>window.location='blogview.asp?id="&request("id")&"'</script>")
 End Sub
 '********************************************
'回复信息过滤
'str--要过滤的字符串
'********************************************
Function filterCmt(str)
Dim re
Set re=new regexp
re.ignorecase=True
re.multiline=True
re.global=True
re.pattern="<script(.*?)</script>"
str=re.Replace(str,"")
re.pattern="<ifram(.*?)</ifram>"
str=re.Replace(str,"")
filterCmt=str
End Function
'********************************************
'修正连接 如果没有http://就添加
'str--要检测的字符串
'********************************************
function checkhttp(str)
if instr(str,"http://")=0 then
	checkhttp="http://"&str
else
	checkhttp=str
end if
end Function

'主模板标记替换开始
Dim ExSkin,Head,Body,Bottom,Skin1
Set ExSkin=new Ex_SkinCls
Skin1=ExSkin.GetTxtSkin("default.html")
Body=Replace(Skin1,"$show_log$",show_logmore(ExSkin))
Body=Replace(Body,"$show_info$",ExSkin.Info)
Body=Replace(Body,"$show_login$",ExSkin.Login)
Body=Replace(Body,"$show_calendar$",ExSkin.calendar("","",""))
Set ExSkin=Nothing 
Body=Replace(Body,"$show_logids$",show_logids)
Bottom=ExComm.BottomInfo
'输出内容
Head=Head&"<html xmlns=""http://www.w3.org/1999/xhtml"">"&vbcrlf
Head=Head&"<head>"&vbcrlf
Head=Head&"<meta http-equiv=""content-type"" content=""text/html; charset=gb2312"">"&vbcrlf
Head=Head&"<meta name=""Description"" content="""&Title&""">"&vbcrlf
Head=Head&"<meta name=""Keywords"" content="""&show_blogkeyword&""">"&vbcrlf
Head=Head&"<title>"&title&Application(sn&"IndexAddWord")&"</title>"&vbcrlf
Head=Head&"<script src=""inc/Main.js""></script>"&vbcrlf
Head=Head&"<script src=""inc/UserInfo.js""></script>"&vbcrlf
Head=Head&"<script src=""inc/jquery.js""></script>"
Head=Head&"<script src=""wbTextBox/kindeditor.js""></script>"
Head=Head&"<link href=""inc/OblogSkin.Css"" rel=""stylesheet"" type=""text/css"" />"&vbcrlf
Head=Head&"</head>"&vbcrlf
Head=Head&"<body>"&vbcrlf
If ExComm.IsOblogSkin Then 
	Response.Write Head
	Response.Write Body
	Response.Write "</body></html>"
Else
	Body=Replace(Body,"$show_logids$",show_logids)
	Body=Replace(Body,"$show_blogtitle$",title&Application(sn&"TitleAddWord"))
	Body=Replace(Body,"$show_blogkeyword$",show_blogKeyword)
	Body=Replace(Body,"$show_blogdescription$",Title)
	Response.Write Body
End If 
If Application(Sn&"Runmode")<>"静态" Then 
	ExComm.visitorCount
End If
Set ExComm=Nothing 
%>