<%
Dim SendMail

Sub Jmail(email,topic,mailbody)
	on error resume next
	dim JMail
	Set JMail=Server.CreateObject("JMail.Message")
	JMail.silent=true
	JMail.Logging=True
	JMail.Charset="gb2312"
	JMail.MailServerUserName = DownsysClass.setting(11) '您的邮件服务器登录名
	JMail.MailServerPassword = DownsysClass.setting(12) '登录密码
	JMail.ContentType = "text/html"
	JMail.Priority = 1
	JMail.From = DownsysClass.setting(8)  '邮件地址
	JMail.FromName = DownsysClass.setting(0)  '网站名称
	JMail.AddRecipient email
	JMail.Subject = topic
	JMail.Body = mailbody
	JMail.Send (DownsysClass.setting(9))   '发邮件服务器地址
	Set JMail=nothing
	SendMail="OK"
	If err then SendMail="False"
end sub
	
sub Cdonts(email,topic,mailbody)
	on error resume next
	dim  objCDOMail
	Set objCDOMail = Server.CreateObject("CDONTS.NewMail")
	objCDOMail.From = DownsysClass.setting(8)  '邮件地址
	objCDOMail.To = email
	objCDOMail.Subject = topic
	objCDOMail.BodyFormat = 0 
	objCDOMail.MailFormat = 0 
	objCDOMail.Body = mailbody
	objCDOMail.Send
	Set objCDOMail = Nothing
	SendMail="OK"
	If err then SendMail="False"
end sub

sub aspemail(email,topic,mailbody)
	on error resume next
	dim Mailer
	Set Mailer=Server.CreateObject("Persits.MailSender") 
	Mailer.Charset = "gb2312"
	Mailer.IsHTML = True
	Mailer.username = DownsysClass.setting(11)	'服务器上有效的用户名
	Mailer.password = DownsysClass.setting(12)	'服务器上有效的密码
	Mailer.Priority = 1
	Mailer.Host = DownsysClass.setting(9)
	Mailer.Port = 25 ' 该项可选.端口25是默认值
	Mailer.From = DownsysClass.setting(8)   '邮件地址
	Mailer.FromName = DownsysClass.setting(0) ' 该项可选
	Mailer.AddAddress email,email
	Mailer.Subject = topic
	Mailer.Body = mailbody
	Mailer.Send
	SendMail="OK"
	If err then SendMail="False"
end sub
%>