Public Class clsFriendSiteClass
    ''' <summary>
    ''' 获取单条记录
    ''' </summary>
    ''' <param name="ID"></param>
    ''' <returns></returns>
    ''' <remarks></remarks>
    Public Function GetSingle(ByVal ID As Integer) As FriendSiteClass
        Using db As New DB_FriendSiteDataContext
            Return (From c In db.FriendSiteClass _
                    Where c.ID = ID _
                    Select c).FirstOrDefault
        End Using
    End Function
    ''' <summary>
    ''' 获取所有记录
    ''' </summary>
    ''' <returns></returns>
    ''' <remarks></remarks>
    Public Shared Function GetLinq(ByVal SiteID As Integer) As IQueryable(Of FriendSiteClass)
        Dim db As New DB_FriendSiteDataContext
        Return From c In db.FriendSiteClass _
               Where c.SiteID = SiteID _
               Order By c.ID _
               Select c
    End Function
    ''' <summary>
    ''' 删除单个实例
    ''' </summary>
    ''' <param name="ID"></param>
    ''' <returns></returns>
    ''' <remarks></remarks>
    Public Function Delete(ByVal ID As Integer) As Boolean
        Using db As New DB_FriendSiteDataContext
            Dim Del = (From d In db.FriendSiteClass _
                      Where d.ID = ID _
                      Select d).FirstOrDefault
            If Not IsNothing(Del) Then
                db.FriendSiteClass.DeleteOnSubmit(Del)
                Try
                    db.SubmitChanges()
                    Return True
                Catch ex As Exception
                    Return False
                End Try
            Else
                Return False
            End If
        End Using
    End Function
    ''' <summary>
    ''' 删除多个实例
    ''' </summary>
    ''' <param name="ID"></param>
    ''' <returns></returns>
    ''' <remarks></remarks>
    Public Function Delete(ByVal ID() As Integer) As Boolean
        Using db As New DB_FriendSiteDataContext
            Dim Del = From d In db.FriendSiteClass _
                      Where ID.Contains(d.ID) _
                      Select d
            For Each d In Del
                db.FriendSiteClass.DeleteOnSubmit(d)
            Next
            Try
                db.SubmitChanges()
                Return True
            Catch ex As Exception
                Return False
            End Try
        End Using
    End Function
    ''' <summary>
    ''' 添加
    ''' </summary>
    ''' <param name="SiteID"></param>
    ''' <param name="ClassName"></param>
    ''' <returns></returns>
    ''' <remarks></remarks>
    Public Function Insert(ByVal SiteID As Integer, ByVal ClassName As String) As Integer
        Using db As New DB_FriendSiteDataContext
            Dim mNewFriendSiteClass As New FriendSiteClass With {.SiteID = SiteID, .ClassName = ClassName}
            db.FriendSiteClass.InsertOnSubmit(mNewFriendSiteClass)
            Try
                db.SubmitChanges()
                Return mNewFriendSiteClass.ID
            Catch ex As Exception
                Return 0
            End Try
        End Using
    End Function
    ''' <summary>
    ''' 保存
    ''' </summary>
    ''' <param name="SiteID"></param>
    ''' <param name="ClassName"></param>
    ''' <returns></returns>
    ''' <remarks></remarks>
    Public Function Save(ByVal ID As Integer, ByVal SiteID As Integer, ByVal ClassName As String) As Integer
        Using db As New DB_FriendSiteDataContext
            Dim UpdateFriendSiteClass = (From c In db.FriendSiteClass _
                                       Where c.ID = ID _
                                       Select c).FirstOrDefault
            If Not IsNothing(UpdateFriendSiteClass) Then
                With UpdateFriendSiteClass
                    .SiteID = SiteID
                    .ClassName = ClassName

                End With

                Try
                    db.SubmitChanges()
                    Return 1
                Catch ex As Exception
                    Return 0
                End Try
            Else
                Return 0
            End If
        End Using
    End Function
End Class
