<!--#Include File="conn.asp"-->
<!--#Include File="top.asp"-->
<SCRIPT LANGUAGE="JavaScript">
function delad(){
if (confirm("确定要删除这则广告么?删除后不可以再恢复哦!?")){return true;}
return false;
}
</SCRIPT>
<%
Dim pagesize,rs,sql,curpage,strcate,i
Dim id,ADID,ADViews,ADHits,ADType,ADSrc,ADLink,ADAlt,ADWidth,ADHeight,ADNote,ADStopViews,ADStopHits,ADStopDate

pagesize=5		'设置每页显示广告树目

If Request.QueryString("page")="" Then
  	curpage = 1
Else
	curpage = cint(Request.QueryString("page"))
End If

Set rs = Server.CreateObject("ADODB.Recordset")
if Request.QueryString("action")="stop" then
	sql = "SELECT * FROM [ad] where ( ADStopViews <> 0 and ADViews > ADStopViews) or ( ADStopHits <> 0 and ADHits > ADStopHits) or ( DateDiff(day,GetDate(),ADStopDate)<1 ) ORDER BY id DESC"
Else
	sql = "SELECT * FROM [ad] ORDER BY id DESC"
end If
rs.open sql, conn, 1, 1

'监测是否存在错误
If err.number <> 0 Then
	Response.Write "<br><br><div align=center>打开数据库出错,请检查conn.asp中数据库地址是否正确</div>"
	Response.End
End If

If rs.bof or rs.eof Then
	rs.Close
	if Request.QueryString("action")="stop" Then
	%><br>
	<table height="200" border="0" align="center" cellpadding="0" cellspacing="1" Class=TableBorder>
  <tr>
    <td align="center"><font color="#990000">暂时没有过期广告！</font></td>
  </tr>
</table>
<!--#Include File="bottom.asp"-->
	<%Else%><br>
	<table height="200" border="0" align="center" cellpadding="0" cellspacing="1" Class=TableBorder>
  <tr>
    <td align="center">暂时没有任何广告！-- <a href=add.asp>立即添加新广告</a></td>
  </tr>
</table>
<!--#Include File="bottom.asp"-->
	<%
	End If
	Response.End
End If

rs.pagesize = pagesize
rs.absolutepage = curpage
%>
<table height="22" border=0 align=center cellpadding=0 cellspacing=0 Class=TableBorder>
<tr>
  <td width="60" height="22" align="center" class="forumRow"><a href="?page=<%=cstr(curpage)%>&pagesize=<%=pagesize%>">[刷新]</a></td>
  <td width="700" height="22" align=right class="forumRow">
      
      <%If curpage = 1 Then%>
      　    [首页] [上一页]                              
      <%Else%>
      [<a href='?page=1'>首页</a>] [<a href='?page=<%=cstr(curpage-1)%>'>上一页</a>]                              
      <%End If
      If  curpage = rs.pagecount Then%>
      [下一页] [尾页]                              
      <%Else%>
      [<a href='?page=<%=cstr(curpage+1)%>'>下一页</a>] [<a href='?page=<%=cstr(rs.pagecount)%>'>尾页</a>]&nbsp;                    
    <%End If%>  </td>
</tr>
</table>
      <table border="0" align=center cellpadding=3 cellspacing=1 Class=TableBorder>
        <% Do While NOT rs.eof 
		id=rs("id")
		ADID=rs("ADID")
		ADViews=rs("ADViews")
		ADHits=rs("ADHits")
		ADType=rs("ADType")
		ADSrc=rs("ADSrc")
		ADLink=rs("ADLink")
		ADAlt=rs("ADAlt")
		ADSrc=rs("ADSrc")
		ADWidth=rs("ADWidth")
		ADHeight=rs("ADHeight")
		ADNote=rs("ADNote") 
		ADStopViews=rs("ADStopViews")
		ADStopHits=rs("ADStopHits")
		ADStopDate=rs("ADStopDate")%>
        <tr> 
          <td width="25%" height="25" Class=forumrowhighlight>名称：<%=ADID%> <%if IsStop(ADViews,ADStopViews,ADStopHits,ADHits,ADStopDate) Then Response.Write(" <font color=yellow>(已过期)") End If%></td>
          <td width="25%" Class=forumrowhighlight>显示：<%=ADViews%></td>
          <td width="25%" Class=forumrowhighlight>点击：<%=ADHits%></td>
          <td width="25%" Class=forumrowhighlight>管理：<a href="edit.asp?id=<%=id%>">编辑</a>&nbsp;&nbsp;<a href="createjs.asp?id=<%=ADID%>">生成JS</a>&nbsp;&nbsp;<a href="del.asp?id=<%=id%>" onclick='return delad();'>删除</a></td>
        </tr>
        <tr> 
          <td width="50%" height="25" colspan=2 Class=forumrow>广告类型：<%=ShowAdType(ADType,rs("ADSrc"))%></td>
          <td colspan=2 width="50%" Class=forumrow>显示地址：
          <%If ADType<>6 Then%><a href=<%=ADSrc%> target=_blank><font color="#000000"><%=ADSrc%></a><%else%>不显示<%end if%></td>
        </tr>
        <tr> 
          <td height="25" colspan=2 Class=forumrow>链接地址：<a href=<%=ADLink%> target=_blank><font color="#000000"><%=ADLink%></a></td>
          <td colspan=2 Class=forumrow>提示文字：<%=ADAlt%></td>
        </tr>
        <tr> 
          <td height="25" colspan=2 Class=forumrow>广告规格：<%=ADWidth%>×<%=ADHeight%></td>
          <td colspan=2 Class=forumrow>备    注：<%=ADNote%></td>                         
        </tr>
        <% 
        i=i+1
		rs.movenext
		If i>=rs.PageSize Then Exit Do     
		Loop
		%>
        <tr align="center" Class=forumrowhighlight> 
          <td height="25" colspan=6> <center>  第<%=cstr(curpage)%>页　总<%=cstr(rs.pagecount)%>页　本页<%=cstr(i)%>条　总<%=cstr(rs.recordcount)%>条          </td>
        </tr>
</table>
<!--#Include File="bottom.asp"-->
<%
rs.close
set rs=nothing
conn.Close
set conn=nothing

'检测是否过期
function IsStop(ADViews,ADStopViews,ADStopHits,ADHits,ADStopDate)
	IsStop=false
	If ( ADStopViews <> 0 and ADViews > ADStopViews) Then 
		IsStop=true
		Exit function
	ElseIf ( ADStopHits <> 0 and ADHits > ADStopHits) Then
		IsStop=true
		Exit function
	ElseIf ( DateDiff("d",Now(),ADStopDate)<1 ) Then	
		IsStop=true
		Exit function
	End If
end function

'判断广告类型
function ShowAdType(ADType,ADSrc)
	Dim ADExt
	ADExt="图片"
	If InStr(1,ADSrc,".swf",1)>0 Then ADExt="FLASH"
	Select Case ADType
		Case 1
			ShowAdType="普通"&ADExt
		Case 2
			ShowAdType="全屏浮动"&ADExt
		Case 3
			ShowAdType="上下浮动 - 右"&ADExt
		Case 4
			ShowAdType="上下浮动 - 左"&ADExt
		Case 5
			ShowAdType="渐隐消失"&ADExt
		Case 6
			ShowAdType="网页对话框"
		Case 7
			ShowAdType="移动透明对话框"
		Case 8
			ShowAdType="打开新窗口"
		Case 9
			ShowAdType="弹出新窗口"
		Case 10 
			ShowAdType="对联式广告"
		Case else
			ShowAdType="<font color=red><b>错误!将不能正确显示</b>"
	End Select
end function
%>