<!--#Include File="../Inc/Const.Asp"-->
<!--#Include File="Inc/Class_Content.Asp"-->
<!DOCTYPE html PUBLIC "-//W3C//DTD XHTML 1.0 Transitional//EN" "http://www.w3.org/TR/xhtml1/DTD/xhtml1-transitional.dtd">
<html xmlns="http://www.w3.org/1999/xhtml">
<head>
<meta http-equiv="Content-Type" content="text/html; charset=UTF-8" />
<title>新闻管理</title>
<script language="JavaScript" type="text/javascript" src="Images/ajax.js"></script>
<script language="javascript" src="ckeditor/ckeditor.js"></script>
<script language="javascript" src="ckfinder/ckfinder.js"></script>
<link href="Images/Style.Css" rel="stylesheet" type="text/css" />
</head>
<body>
<%

If Len(Request.Form("oContent")) > 0 And getReq("Act") = "UpDate" Then Session("Content_IN_Cache") = Request.Form("oContent")

Dim U
Set U = New Cls_Content

Dim Rs,Ns,Sql,Style,i
Dim ID,Key,Page,Orders,DFieldKey,DfieldOrders
    ID = getReq("ID"):Key = getReq("Key"):Page = getReq("Page"):Orders = getReq("Orders"):DFieldKey = getReq("DFieldKey"):DFieldOrders = getReq("DFieldOrders")
If len(ID) > 0 And Not IsNumeric(ID) Then : Response.Write "ID错误!" : Conn.Close : Set Conn = Nothing : Set U = Nothing : Response.End '// 检测ID
If Len(Page) = 0 Or Not IsNumeric(ID) Then Page = 1
If Page < 1 Then Page = 1
If LCase(Orders) <> "asc" Then Orders = "Desc"
If Len(DFieldKey) = 0 Then DFieldKey = "Title"
If Len(DFieldOrders) = 0 Then DFieldOrders = "ID"
If Instr("[id],[cid],[title],[commend],[views],[comments],[order],[filepath],[display]" , "[" & Lcase(DFieldKey) & "]") = 0 Then Key = ""
If Instr("[id],[cid],[title],[commend],[views],[comments],[order],[filepath],[display]" , "[" & Lcase(DFieldOrders) & "]") = 0 Then DFieldOrders = "ID"
Page = Int(Page) : Key = Replace(Key,"'","")
Dim JumpUrl
    JumpUrl = "&Key=" & Server.UrlENCode(Key) & "&DFieldKey=" & DFieldKey & "&Orders=" & Orders & "&DFieldOrders=" & DFieldOrders

Select Case Request("Act")
Case "Guide"
	If Len(ID) = 0 Then
		Call U.Initialize()
		Call Main_Guide(0)
	Else
		U.vID = ID
		Call U.SetValue()
		Call Main_Guide(1)
	End If
Case "UpDate"
	If U.GetValue() Then '如果U.GetValue()正常执行
		If Len(ID) = 0 Then '如果是新增数据
			If Not U.Create() Then '如果U.
				Alert U.LastError,"Manage_News.asp?Page=" & Page & JumpUrl
			Else
				Alert "","Manage_News.asp?Page=" & Page & JumpUrl
			End If
		Else
			U.vID = ID
			If Not U.Modify() Then
				Alert U.LastError,"Manage_News.asp?Page=" & Page & JumpUrl
			Else
				Alert "","Manage_News.asp?Page=" & Page & JumpUrl
			End If
		End If
	Else
		Alert U.LastError,"Manage_News.asp?Page=" & Page & JumpUrl
	End If
Case "Delete"
	If Len(ID) > 0 Then
		U.vID = ID
		If Not U.Delete() Then
			Alert U.LastError,"Manage_News.asp?Page=" & Page & JumpUrl
		Else
			Alert "","Manage_News.asp?Page=" & Page & JumpUrl
		End If
	Else
		Call Main()
	End If
Case "Change"
	If Len(ID) > 0 Then
		U.vID = ID
		If Not U.Change() Then Alert U.LastError,""
	End If
	Call Main()
Case "DOCreate"
	ID = Split(Replace(Replace(Request("ids"),"'","")," ",""),",")
	For i = 0 To Ubound(ID)
		Call CreateContent(ID(i),0)
	Next
	Call Main()
Case "DODelete"
	ID = Replace(Replace(Request("ids"),"'","")," ","")
	Call U.DeleteAll(ID)
	Call Main()
Case "DOMove"
	ID = Replace(Replace(Request("ids"),"'","")," ","")
	Call U.EchoMoveHtml(ID)
Case "DOMoveit"
	Dim Tmp
	Dim Tocid : Tocid = Request("Tocid")
	Call U.MoveContent(Tocid,ID)
	Call Main()
Case Else
	Call Main()
End Select

Set U = Nothing
If IsObject(Conn) Then Conn.Close : Set Conn = Nothing

Sub Main()
If Len(Key) > 0 Then
	If Instr(",ID,Cid,Commend,Views,Comments,Orders,Display,","," & DFieldKey & ",") > 0 Then
		If Len(Key) > 0 And IsNumeric(Key) Then Sql = "[" & DFieldKey & "]=" & Key & ""
	Else
		Sql = "[" & DFieldKey & "] Like '%" & Key & "%'"
	End If
End If

Dim SQLCID
If Len(getLogin("admin","managechannel")) = 0 Then
	SQLCID = "CID=0"
Else
	If Cstr(getLogin("admin","managechannel")) <> Cstr("0") Then
		SQLCID = "CID IN (" & getLogin("admin","managechannel") & ")"
	End If
End If

' 栏目权限
If Len(SQL) > 0 Then
	If LEN(SQLCID) > 0 Then SQL = SQL & " and " & SQLCID
Else
	If LEN(SQLCID) > 0 Then SQL = SQLCID
ENd If

Set Rs = New DataList
Rs.Field = "[ID],[Cid],[Title],[Commend],[Views],[Order],[Filepath],[Display],[Indexpic]"
Rs.Table = "[{pre}Content]"
Rs.Where = SQL
Rs.Order = "[" & DFieldOrders & "] " & Orders & ""
Rs.AbsolutePage = Page
Rs.List()
%>
<table width=100% border=0 cellpadding=3 cellspacing=1 class=css_table bgcolor='#E1E1E1'>
	<tr class="css_menu">
		<td colspan="8"><table width="100%" border="0" cellpadding="4" cellspacing="0" class="css_main_table">
				<form name="frmSearch" method="post" action="Manage_News.asp">
					<tr>
						<td class="css_main"><a href="Manage_News.asp">内容管理</a> <a href="Manage_News.asp?Act=Guide&Page=<%=Page%><%=JumpUrl%>">添加内容</a></td>
						<td class="css_search"><select name="DFieldKey" id="DFieldKey">
								<option value="ID" <%If Lcase(DFieldKey) = "id" Then Response.Write "selected='selecte'" %>>编号</option>
								<option value="Cid" <%If Lcase(DFieldKey) = "cid" Then Response.Write "selected='selected'" %>>栏目</option>
								<option value="Title" <%If Lcase(DFieldKey) = "title" Then Response.Write "selected='selected'" %>>标题</option>
								<option value="Display" <%If Lcase(DFieldKey) = "display" Then Response.Write "selected='selected'" %>>前台显示</option>
							</select>
							<input name="Key" type="text" id="Key" size="10" value="<%=Key%>">
							<input type="submit" name="Submit" value="搜"></td>
					</tr>
				</form>
			</table></td>
	</tr>
	<form name="frm" method="post" action="Manage_News.asp">
		<tr>
			<td width="30" class='css_top'><input type="checkbox" name="chkall" id="chkall" onclick="CheckAll()" class="checkbox"></td>
			<td width="38" class='css_top'>编号</td>
			<td class='css_top'>标题</td>
			<td width="38" class='css_top'><a href='Manage_News.asp?Page=<%=Page%>&DFieldOrders=Views&Orders=<%If Lcase(DFieldOrders) = Lcase("Views") And Orders = "Desc" Then Response.Write "Asc" Else Response.Write "Desc" %>'>浏览</a></td>
			<td width="38" class='css_top'><a href='Manage_News.asp?Page=<%=Page%>&DFieldOrders=Orders&Orders=<%If Lcase(DFieldOrders) = Lcase("Orders") And Orders = "Desc" Then Response.Write "Asc" Else Response.Write "Desc" %>'>权重</a></td>
			<td width="38" class='css_top'><a href='Manage_News.asp?Page=<%=Page%>&DFieldOrders=Commend&Orders=<%If Lcase(DFieldOrders) = Lcase("Commend") And Orders = "Desc" Then Response.Write "Asc" Else Response.Write "Desc" %>'>推荐</a></td>
			<td width="38" class='css_top'><a href='Manage_News.asp?Page=<%=Page%>&DFieldOrders=Display&Orders=<%If Lcase(DFieldOrders) = Lcase("Display") And Orders = "Desc" Then Response.Write "Asc" Else Response.Write "Desc" %>'>状态</a></td>
			<td width="90" class='css_top'>管理</td>
		</tr>
		<%
		If Rs.Eof Then
		%>
		<tr align="center" class="css_norecord">
			<td colspan="8">没有任何记录！</td>
		</tr>
		<%
		Else
		Dim Hivepic
		For i = 0 To UBound(Rs.Data,2)
		If Len(Rs.Data(8,i)) > 0 Then Hivepic = " <font color=#FFB9B9>图</font>" Else Hivepic = ""
		%>
		<tr bgcolor="#fbfbfb" onMouseMove="javascript:this.bgColor='#cedcf0';" onMouseOut="javascript:this.bgColor='#FBFBFB';" >
			<td width="30" class='css_list'><input type="checkbox" name="ids" value="<%=Rs.Data(0,i)%>" class="checkbox"></td>
			<td width="38" class='css_list'><%=Rs.Data(0,i)%></td>
			<td class='css_list'><div align="left"> [<a href=Manage_News.asp?Key=<%=Rs.Data(1,i)%>&DFieldKey=Cid><%=GetChannel(Rs.Data(1,i),"Name")%></a>] &nbsp;<a href="Manage_News.asp?Act=Guide&ID=<%=Rs.Data(0,i)%>&Page=<%=Page%><%=JumpUrl%>"><%=Rs.Data(2,i)%></a> <a href="<%="../redirect.asp?" & Rs.Data(0,i)%>" target="_blank"><font color=#999999>预</font></a><%=Hivepic%> </div></td>
			<td width="38" class='css_list'><%=Rs.Data(4,i)%></td>
			<td width="38" class='css_list'><%=Rs.Data(5,i)%></td>
			<td width="38" class='css_list'><span id="ContentCommend<%=Rs.Data(0,i)%>" style="cursor:hand;" onclick="ContentCommend(<%=Rs.Data(0,i)%>);"><%
			Select Case Cstr(LCase(Rs.Data(3,i)))
			Case "0" Response.Write "普通"
			Case "1" Response.Write "<font color=red>推荐</font>"
			Case Else Response.Write Rs.Data(2,i)
			End Select
			%></span></td>
			<td width="38" class='css_list'><span id="ContentState<%=Rs.Data(0,i)%>" style="cursor:hand;" onclick="ContentState(<%=Rs.Data(0,i)%>);"><%
			Select Case Cstr(LCase(Rs.Data(7,i)))
			Case "0" Response.Write "<font color=blue>隐藏</font>"
			Case "1" Response.Write "显示"
			Case Else Response.Write Rs.Data(7,i)
			End Select
			%></span></td>
			<td width="90" class='css_list'><input name=modify type=button onclick="location.href='Manage_News.asp?Act=Guide&ID=<%=Rs.Data(0,i)%>&Page=<%=Page%><%=JumpUrl%>';" value="修改">
				<input name=delete type=button onclick="if(confirm('您确定要删除这条记录吗?')){location.href='Manage_News.asp?Act=Delete&ID=<%=Rs.Data(0,i)%>&Page=<%=Page%><%=JumpUrl%>';}" value=删除></td>
	  </tr>
		<%
		Next
		End If
		%>
		<tr class=css_page_list>
			<td colspan=8><%If Createhtml=1 Then%>
				<input type="button" class="inputs" onclick="ContentDo('DOCreate');" value="生成" />
				<%End If%>
				<input name="" type="button" class="inputs" onclick="ContentDo('DODelete');" value="删除" />
				<input name="" type="button" class="inputs" onclick="ContentDo('DOMove');" value="移动" />
				&nbsp;
				<select name='Jcid' onchange='location.href=this.options[this.selectedIndex].value;' >
					<option value='Manage_News.asp' selected style='background-color:#F0F9E3;'>不指定栏目</option>
					<%Set Ns = DB("Select [ID],[Name] From [{pre}Channel] Where [OutSideLink]=0 Order By [Order] Desc,[ID] Desc",1)%> <%Do While Not Ns.Eof%>
					<option value='Manage_News.asp?Page=1&Key=<%=Ns(0)%>&DFieldKey=Cid' <%If DFieldKey="Cid" And Cstr(Key)=Cstr(Ns(0)) Then%>selected<%End If%>><%=Ns(1)%></option>
					<%Ns.MoveNext : Loop%>
				</select>
				<%=PageList(Rs.PageCount,Page,Rs.RecordCount,15,"Manage_News.asp?Page={p}&Key=" & Server.UrlENCode(Key) & "&DFieldKey=" & DFieldKey & "&Orders=" & Orders & "&DFieldOrders=" & DFieldOrders)%></td>
		</tr>
	</form>
</table>
<%
Set Rs = Nothing
End Sub

Sub Main_Guide(T)
	%>
<%If IsNull(U.vCommend) Then U.vCommend=""%> <%If IsNull(U.vIsComment) Then U.vIsComment=""%> <%If IsNull(U.vDisplay) Then U.vDisplay=""%> <%If IsNull(U.vStyle) Then U.vStyle=""%> <%If IsNull(U.vColor) Then U.vColor=""%>
<table width=100% border=0 cellpadding=3 cellspacing=1 class=css_table bgcolor='#E1E1E1'>
	<tr class=css_menu>
		<td colspan=5><table width=100% border=0 cellpadding=4 cellspacing=0 class=css_main_table>
				<tr>
					<td class=css_main><a href=Manage_News.asp?Page=<%=Page%><%=JumpUrl%>>内容管理</a></td>
				</tr>
			</table></td>
	</tr>
	<form name='frm' method='post' action='Manage_News.asp?Act=UpDate&ID=<%=ID%>&Page=<%=Page%><%=JumpUrl%>'>
		<tr>
			<td width="94" class="css_col12_content"><div align="right"> <font color=red>栏目：</font> </div></td>
			<td colspan="4" class="css_col22"><%If IsNull(U.vCid) Then U.vCid=""%> <%If Not IsNumeric(U.vCid) Then U.vCid="" Else U.vCid = Int(U.vCid)%> <%=SelectChannel(U.vCid," class='css_select' name=""oCid"" type=""text"" id=""oCid"" ",getLogin("admin","managechannel"))%> <%If IsNull(U.vSid) Then U.vSid=""%> <%If Not IsNumeric(U.vSid) Then U.vSid="" Else U.vSid = Int(U.vSid)%> <%'SelectChannel(U.vSid," class='css_select' name=""oSid"" type=""text"" id=""oSid"" ",getLogin("admin","managechannel"))%></td>
		</tr>
		<tr>
			<td class="css_col11_content"><div align="right"> <font color=red>标题：</font> </div></td>
			<td colspan="4" class="css_col21"><input name="oTitle" type="text" class="css_input" id="oTitle" <%if len(u.vtitle) = 0 then%>onblur="ChkTitle()"<%End If%> value="<%=U.vTitle%>" size="70" />
				<input name="oCommend" type="checkbox" value="1" <%If U.vCommend = 1 Then Response.Write "checked='checked'"%> /> 推荐
				<input name="oIsComment" type="checkbox" value="1" <%If U.vIsComment = 1 Then Response.Write "checked='checked'"%> /> 评论
				<input name="oDisplay" type="checkbox" value="1" <%If U.vDisplay = 1 Then Response.Write "checked='checked'"%> /> 发布
			</td>
		</tr>
		<tr>
			<td class=css_col12_content><div align="right"> 属性： </div></td>
			<td colspan="4" class=css_col22><table border="0" cellpadding="0" cellspacing="0">
					<tr>
						<td><input name="oAuthor" type="text" class='css_input' id="oAuthor" value="<%=U.vAuthor%>" size="6">
							<select name="select" onchange="frm.oAuthor.value=this.value;">
								<option>清空</option>
								<%
								Author = Split(Author,",")
								For i = 0 To Ubound(Author)
								Response.Write "<option value='" & Author(i) & "' "
								If LCase(Author(i)) = LCase(U.vAuthor) Then Response.Write "selected"
								Response.Write " >" & Author(i) & "</option>"
								Next
								%>
							</select>						</td>
						<td width="10">&nbsp;</td>
						<td>来源：</td>
						<td><input name="oSource" type="text" class='css_input' id="oSource" value="<%=U.vSource%>" size="6" />
							<select name="select2" onchange="frm.oSource.value=this.value;">
								<option>清空</option>
								<%
								Source = Split(Source,",")
								For i = 0 To Ubound(Source)
								Response.Write "<option value='" & Source(i) & "' "
								If LCase(Source(i)) = LCase(U.vSource) Then Response.Write "selected"
								Response.Write " >" & Source(i) & "</option>"
								Next
								%>
							</select>						</td>
						<td width="10"></td>
						<td>浏览：</td>
						<td><input class='css_input' name="oViews" type="text" id="oViews" value="<%=U.vViews%>" size=2 />						</td>
						<td width="10">&nbsp;</td>
						<td>权重：</td>
						<td><input class='css_input' name="oOrder" type="text" id="oOrder" value="<%=U.vOrder%>" size=2 />						</td>
						<td width="10">&nbsp;</td><td><select class='css_select' name="oStyle" type="text" id="oStyle">
					<option value="" <%If U.vStyle = "" Then Response.Write "selected"%>>样式</option>
					<option value="strong" <%If U.vStyle = "strong" Then Response.Write "selected"%>>粗体</option>
					<option value="em" <%If U.vStyle = "em" Then Response.Write "selected"%>>斜体</option>
				</select></td><td width="10">&nbsp;</td>
						<td><select class='css_select' name="oColor" type="text" id="oColor">
					<option value="" <%If U.vColor = "" Then Response.Write "selected"%>>颜色</option>
					<option value="#FF0000" style="background-color:#FF0000;" <%If U.vColor = "#FF0000" Then Response.Write "selected"%>></option>
					<option value="#0000FF" style="background-color:#0000FF;" <%If U.vColor = "#0000FF" Then Response.Write "selected"%>></option>
					<option value="#00FFFF" style="background-color:#00FFFF;" <%If U.vColor = "#00FFFF" Then Response.Write "selected"%>></option>
					<option value="#FF9900" style="background-color:#FF9900;" <%If U.vColor = "#FF9900" Then Response.Write "selected"%>></option>
					<option value="#339966" style="background-color:#339966;" <%If U.vColor = "#339966" Then Response.Write "selected"%>></option>
				</select></td>
						
				
					</tr>
				</table></td>
		</tr>
		<%
		If T = 0 Then 
			Style=""
		Else
			If ChangDiyname = 1 Then Style="" Else Style=" style='display:none;'"
		End If
		%>
		<tr <%=Style%>>
			<td class="css_col11_content"><div align="right"> 文件名： </div></td>
			<td colspan="4" class="css_col21"><input name="oDiyname" type="text" class="css_input" id="oDiyname" onblur="ChkDiyname('<%=U.vID%>');" value="<%=U.vDiyname%>" size="32" />
				<input name="oAutopinyin" type="checkbox" id="oAutopinyin" value="Yes" <%If Autopinyin = 1 And Len(U.vTitle)=0 Then Response.Write "checked='checked'"%> />
				将标题转换成拼音 (如果填写了文件名则不转换成拼音) </td>
		</tr>
		<tr>
			<td class="css_col12_content"><div align="right"> 关键字： </div></td>
			<td colspan="4" class="css_col22"><input name="oKeywords" type="text" class='css_input' id="oKeywords" value="<%=Server.HtmlEnCode(U.vKeywords)%>" size="32" />
				<input name="checkbox4" type="checkbox" onclick="if (this.checked) {ShowObj('trdescription');} else {HideObj('trdescription')}" value="checkbox" />
				<font color="red"><%=IIf(DescriptionUpdate = 0 ,"手动","自动")%></font>编辑描述 (多个关键字请用英文状态下的逗号分隔) </td>
		</tr>
		<tr id='trjumpurl'>
			<td class="css_col11_content"><div align="right"> 跳转地址： </div></td>
			<td colspan="3" class=css_col21><input name="oJumpurl" type="text" <%If Len(U.vJumpurl) = 0 Then Response.Write "disabled='disabled'"%> class="css_input" id="oJumpurl" value="<%=U.vJumpurl%>" size="54" ><input name="checkbox" type="checkbox" onclick="if (this.checked) {HideObj('trcontent');frm.oJumpurl.disabled=false;if(frm.oJumpurl.value.length==0){frm.oJumpurl.value='http://';ShowObj('trdescription');}} else {ShowObj('trcontent');HideObj('trdescription');frm.oJumpurl.disabled=true;frm.oJumpurl.value='';}" value="checkbox" <%If Len(U.vJumpurl) > 0 Then Response.Write "checked='checked'"%> /> 跳转			</td>
			<td width="160" rowspan="3" class=css_col21><div id="indexpicimg" align="center"> <%If Len(U.vIndexpic) > 0 Then%> <img src="<%=U.vIndexpic%>" height=95 width=150 /> <%Else%> <img src="Images/nopic.gif" height=95 width=150 /> <%End If%> </div></td>
		</tr>
		<tr>
			<td class="css_col11_content"><div align="right"> 形象图： </div></td>
			<td colspan="3" class="css_col21"><input class='css_input' name="oIndexpic" type="text" id="oIndexpic" value="<%=U.vIndexpic%>" size=32 >
				<select name="indexpiclist" id="indexpiclist" onchange="frm.oIndexpic.value=this.value; if(this.value.length>0){indexpicimg.innerHTML='<img src=' + this.value + ' height=95 width=150 />';}else{indexpicimg.innerHTML='<img src=Images/nopic.gif height=95 width=150 />';}">
					<option value="">不指定文章形象图</option>
					<%
					If T = 1 Then
						Dim Pic
						Set Pic = DB("Select [Dir],[Ext] From [{pre}Upload] Where [Aid]=" & U.vID & " Order By [Time] Desc",1)
						Do While Not Pic.EOf
							If Instr("gif,jpg,jpeg,bmp,png",LCase(Pic(1))) Then
								Response.Write "<option value='" & Pic(0) & "' "
								If LCase(Pic(0)) = LCase(U.vIndexpic) Then Response.Write "selected"
								Response.Write " >" & Replace(LCase(Pic(0)),"/uploadfile","") & "</option>"
							End If
							Pic.MoveNext
						Loop
					End If
					%>
				</select>			</td>
		</tr>
		<tr>
			<td class="css_col11_content"><div align="right"> 上传文件： </div></td>
			<td class="css_col21"><iframe name='uploadframe' src="Upload.Asp" width="372" height="24" frameborder="0" scrolling="no" border="0"></iframe></td>
			<td width="88" class="css_col21" onclick=""></td>
			<td width="88" class="css_col21"><div align="center">
					<input name="oRemotepic" type="checkbox" id="oRemotepic" value="Save" <% If Remotepic = 1 Then Response.Write "checked='checked'"%> />
					远程抓图 </div></td>
		</tr>
		<tr style='display:none;' id="trdescription">
			<td class="css_col11_content"><div align="right"> 描述： </div></td>
			<td colspan="4" class="css_col21"><textarea name="oDescription" style="width:99%;" rows="3" class='css_textarea' id="oDescription" type="text"><%If DescriptionUpdate = 0 Then Response.WRite U.vDescription%></textarea>			</td>
		</tr>
		<tr id="trcontent"  <%If Len(U.vJumpurl) > 0 Then Response.Write " style='display:none;'"%> >
			<td class="css_col11_content"><div align="right"> <font color="red">内容：</font></div></td>
			<td colspan="4" class="css_col21">
            <textarea name="oContent" class="ckeditor" id="oContent" style="width:100%;height:350px;" >
<%=U.vContent%></textarea>
<script language="javascript">                    
                   if(typeof CKEDITOR=='undefined') {
		document.write('加载CKEditor失败')
}else{
CKFinder.setupCKEditor( null, { basePath : 'ckfinder/', rememberLastFolder :false } ) ;
}

CKEDITOR.replace( 'oContent',
{
	toolbar : 'Full', 
	filebrowserBrowseUrl : 'ckfinder/ckfinder.html',
	filebrowserImageBrowseUrl : 'ckfinder/ckfinder.html?type=Images',
	filebrowserFlashBrowseUrl : 'ckfinder/ckfinder.html?type=Flash',
	filebrowserUploadUrl : 'ckfinder/core/connector/asp/connector.asp?command=QuickUpload&type=Files',
	filebrowserImageUploadUrl : 'ckfinder/core/connector/asp/connector.asp?command=QuickUpload&type=Images',
	filebrowserFlashUploadUrl : 'ckfinder/core/connector/asp/connector.asp?command=QuickUpload&type=Flash',
	filebrowserWindowWidth : '800',
	filebrowserWindowHeight : '600'
});

</script>
            
            </td>
		</tr>
		<tr class="css_page_list">
			<td colspan="5"><input name='Submit' type='button' onclick="ChkPost()" value='保存'>			</td>
		</tr>
	</form>
</table>
<%
End Sub
%>

</body>
</html>
