<%
'**************************************
'* 最后更新 2012-06-18 by 56770.Kingdge
'* Copyright www.56770.com
'*************************************
strwebtitle = Lebi_cart(188) &"-"
description = Replace(safereplace(Sys_description)," ","")
keywords = Replace(safereplace(Sys_keywords)," ","")
Showpath = "<a href='"& Eshop_url & LangPath &"'>"& Lebi_word(0) &"</a> → "& Lebi_cart(188) &""
sitename = site_name
page = checknum(request("page"),1)
other_main = ShipmentMessageList(1,1)

Function ShipmentMessageList(showheadpage,showfootpage)
        Dim DataCount,DataList,Filename,i,j,RLoadStyle(5),strFile,tmpstr,loopstr, LoadListStr
        showheadpage = checknum(showheadpage,0) : showfootpage = checknum(showfootpage,0)
	    Dim ors,sqlwhere
	    Set ors=new Cls_vbsPage
	    Set ors.Conn=conn
	    With ors
		    .PageSize=20
		    .PageName="Page"
			If IsSqlDataBase = 0 Then
		            .DbType="AC"
			Else
			        .DbType="MSSQL"
			End If
		    .RecType=-1
		    .Pkey="s_id"
    	    .Field="s_id,s_order_number,s_name,s_no,s_user_name,s_date,s_fei1,s_fei2"
		    .Table="Lebi_ShipMes"
			.Condition = ""
            .OrderBy="s_id desc"
	    End With
	    DataCount=ors.RecCount()
	    DataList=ors.ResultSet()
		strFile = Eshop_url& Style_Folder &"Lebi.ShipmentMessageList."
		LoadListStr = LoadStyle(strFile&"0.style")
		Filename = "default.asp"
		If showheadpage = 1 Then
				tmpstr = LoadStyle(strFile&"1.style")
				ReplaceStyle "headpage",ors.ShowPageHead(Filename),tmpstr
				LoadListStr = LoadListStr & tmpstr
		End If
	    If DataCount > 0 Then
				LoadListStr = LoadListStr & splits(LoadStyle(strFile&"3.style"))
				RLoadStyle(4) = splits(LoadStyle(strFile&"4.style"))
		        For i = 0 To Ubound(DataList,2)
				        loopstr = RloadStyle(4)
						ReplaceStyle "order_number",DataList(1,i),loopstr
						ReplaceStyle "name",DataList(2,i),loopstr
						ReplaceStyle "number",DataList(3,i),loopstr
						ReplaceStyle "username",DataList(4,i),loopstr
						ReplaceStyle "time",DataList(5,i),loopstr
						ReplaceStyle "price1",dw & formatnumber2(DataList(6,i)) & dw2,loopstr
						ReplaceStyle "price2",dw & formatnumber2(DataList(7,i)) & dw2,loopstr
						ReplaceStyle "loop_num",i + 1,loopstr
						LoadListStr = LoadListStr & loopstr
                Next
		Else
				LoadListStr = LoadListStr & splits(LoadStyle(strFile&"2.style"))
        End If
		LoadListStr = LoadListStr & LoadStyle(strFile&"5.style")
		If showfootpage = 1 Then
				tmpstr = LoadStyle(strFile&"6.style")
				ReplaceStyle "footpage",ors.ShowPageFoot(Filename),tmpstr
				LoadListStr = LoadListStr & tmpstr
		End If
		LoadListStr = LoadListStr & LoadStyle(strFile&"7.style")
		ShipmentMessageList = LoadListStr
End Function
%>