<!--#Include File="Include.asp"--><%
'--------------------------------------
'Power By 580Web @2010-2014 f02
'URL:http://www.580Web.Cn/
'EMail:wsok85@qq.com
'QQ:253819801
'版权所有 未经允许不得去除本版权信息
'--------------------------------------

Call CheckAdminType("0,1",UType)
Call CheckAdminLimit(ULimit,"o_Friends",0)

Dim Fk_FriendsType_Name

Types=Clng(Request.QueryString("Type"))

Select Case Types
	Case 1
		Call FriendsTypeList() '友情链接类型列表
	Case 2
		Call FriendsTypeAddForm() '添加友情链接类型表单
	Case 3
		Call FriendsTypeAddDo() '执行添加友情链接类型
	Case 4
		Call FriendsTypeEditForm() '修改友情链接类型表单
	Case 5
		Call FriendsTypeEditDo() '执行修改友情链接类型
	Case 6
		Call FriendsTypeDelDo() '执行删除友情链接类型
	Case Else
		Call FKFun.ShowErr("未发现功能项！",1)
End Select

'==========================================
'函 数 名：FriendsTypeList()
'作    用：友情链接类型列表
'==========================================
Sub FriendsTypeList()
%>
		<div id="rightNav">
			<ul>
				<li><a href="FriendsType.asp?Type=2" target="dialog" width="500">添加友情链接类型</a></li>
			</ul>
		</div>
		<div id="searchLine" class="font_bold">
			友情链接类型管理
		</div>
		<table width="100%" bordercolor="#CCCCCC" border="1" cellspacing="0" cellpadding="0">
			<tr>
				<th align="center">ID</th>
				<th align="center">名称</th>
				<th align="center">操作</th>
			</tr>
<%
	Sqlstr="Select Fk_FriendsType_Id,Fk_FriendsType_Name From [Fk_FriendsType] Order By Fk_FriendsType_Id Asc"
	Rs.Open Sqlstr,Conn,1,1
	If Not Rs.Eof Then
		i=1
		While Not Rs.Eof
%>
			<tr>
				<td height="20" align="center"><%=Rs("Fk_FriendsType_Id")%></td>
				<td align="center"><%=Rs("Fk_FriendsType_Name")%></td>
				<td align="center"><a href="FriendsType.asp?Type=4&Id=<%=Rs("Fk_FriendsType_Id")%>" target="dialog" width="500">修改</a> <a href="FriendsType.asp?Type=6&Id=<%=Rs("Fk_FriendsType_Id")%>" target="delete" confirmStr="您确认要删除“<%=Rs("Fk_FriendsType_Name")%>”？此操作不可逆！" refreshUrl="FriendsType.asp?Type=1" showStr="名称删除成功！">删除</a></td>
			</tr>
<%
			Rs.MoveNext
			i=i+1
		Wend
	Else
%>
			<tr>
				<td height="25" colspan="20" align="center">暂无记录</td>
			</tr>
<%
	End If
	Rs.Close
%>
			<tr>
				<td height="30" colspan="20">&nbsp;</td>
			</tr>
		</table>
		<div id="rightBottom">
		
		</div>
<%
End Sub

'==========================================
'函 数 名：FriendsTypeAddForm()
'作    用：添加友情链接类型表单
'==========================================
Sub FriendsTypeAddForm()
%>
<form id="FriendsTypeAdd" name="FriendsTypeAdd" method="post" target="ajax" action="FriendsType.asp?Type=3" showStr="新友情链接类型添加成功！" refreshUrl="FriendsType.asp?Type=1" boxClose="1">
<div id="title">添加新友情链接类型</div>
<div id="box">
	<table width="90%" border="1" bordercolor="#CCCCCC" align="center" cellpadding="0" cellspacing="0">
		<tr>
			<td width="24%" height="30" align="right">名称：</td>
			<td width="76%">&nbsp;<input name="Fk_FriendsType_Name" type="text" class="input" id="Fk_FriendsType_Name" /><span class="help" title="<p>友情链接类型名称，请输入1-50个字符（两个字符为一个汉字）。</p>"></span></td>
		</tr>
	</table>
</div>
<div id="bottom">
	<input type="submit" class="button" name="Enter" id="Enter" value="添 加" />
	<input type="button" onclick="dialogClose();" class="button" name="button" id="button" value="关 闭" />
</div>
</form>
<%
End Sub

'==============================
'函 数 名：FriendsTypeAddDo
'作    用：执行添加友情链接
'==============================
Sub FriendsTypeAddDo()
	Fk_FriendsType_Name=FKFun.HTMLEncode(Trim(Request.Form("Fk_FriendsType_Name")))
	Call FKFun.JsonString(Fk_FriendsType_Name,1,50,0,"请输入名称！","名称不能大于50个字符！")
	Sqlstr="Select Fk_FriendsType_Id,Fk_FriendsType_Name From [Fk_FriendsType] Where Fk_FriendsType_Name='"&Fk_FriendsType_Name&"'"
	Rs.Open Sqlstr,Conn,1,3
	If Rs.Eof Then
		Application.Lock()
		Rs.AddNew()
		Rs("Fk_FriendsType_Name")=Fk_FriendsType_Name
		Rs.Update()
		Application.UnLock()
		Call FKFun.JsonSuccess()
	Else
		Rs.Close
		Call FKFun.JsonError("该友情链接类型名称已经被占用！")
	End If
	Rs.Close
End Sub

'==========================================
'函 数 名：FriendsTypeEditForm()
'作    用：修改友情链接表单
'==========================================
Sub FriendsTypeEditForm()
	Id=Clng(Request.QueryString("Id"))
	Sqlstr="Select Fk_FriendsType_Name From [Fk_FriendsType] Where Fk_FriendsType_Id=" & Id
	Rs.Open Sqlstr,Conn,1,1
	If Not Rs.Eof Then
		Fk_FriendsType_Name=Rs("Fk_FriendsType_Name")
	Else
		Rs.Close
		Call FKFun.ShowErr("友情链接类型不存在！",1)
	End If
	Rs.Close
%>
<form id="FriendsTypeEdit" name="FriendsTypeEdit" method="post" target="ajax" action="FriendsType.asp?Type=5" showStr="友情链接类型修改成功！" refreshUrl="FriendsType.asp?Type=1" boxClose="1">
<div id="title">修改友情链接类型</div>
<div id="box">
	<table width="90%" border="1" bordercolor="#CCCCCC" align="center" cellpadding="0" cellspacing="0">
		<tr>
			<td width="24%" height="30" align="right">名称：</td>
			<td width="76%">&nbsp;<input name="Fk_FriendsType_Name" type="text" class="input" id="Fk_FriendsType_Name" value="<%=Fk_FriendsType_Name%>" /><span class="help" title="<p>友情链接类型名称，请输入1-50个字符（两个字符为一个汉字）。</p>"></span></td>
		</tr>
	</table>
</div>
<div id="bottom">
	<input type="hidden" name="Id" value="<%=Id%>" />
	<input type="submit" class="button" name="Enter" id="Enter" value="修 改" />
	<input type="button" onclick="dialogClose();" class="button" name="button" id="button" value="关 闭" />
</div>
</form>
<%
End Sub

'==============================
'函 数 名：FriendsTypeEditDo
'作    用：执行修改友情链接
'==============================
Sub FriendsTypeEditDo()
	Fk_FriendsType_Name=FKFun.HTMLEncode(Trim(Request.Form("Fk_FriendsType_Name")))
	Id=Trim(Request.Form("Id"))
	Call FKFun.JsonString(Fk_FriendsType_Name,1,50,0,"请输入名称！","名称不能大于50个字符！")
	Call FKFun.JsonNum(Id,"系统参数错误，请刷新页面！")
	Sqlstr="Select Fk_FriendsType_Id,Fk_FriendsType_Name From [Fk_FriendsType] Where Fk_FriendsType_Id=" & Id
	Rs.Open Sqlstr,Conn,1,3
	If Not Rs.Eof Then
		Application.Lock()
		Rs("Fk_FriendsType_Name")=Fk_FriendsType_Name
		Rs.Update()
		Application.UnLock()
		Call FKFun.JsonSuccess()
	Else
		Rs.Close
		Call FKFun.JsonError("要修改的友情链接类型不存在！")
	End If
	Rs.Close
End Sub

'==============================
'函 数 名：FriendsTypeDelDo
'作    用：执行删除友情链接
'==============================
Sub FriendsTypeDelDo()
	Id=Trim(Request.QueryString("Id"))
	Call FKFun.ShowNum(Id,"系统参数错误，请刷新页面！")
	Sqlstr="Select Fk_Friends_Id From [Fk_Friends] Where Fk_Friends_FriendsType=" & Id
	Rs.Open Sqlstr,Conn,1,1
	If Not Rs.Eof Then
		Call FKFun.ShowErr("该分类有记录，无法删除！",2)
	End If
	Rs.Close
	Sqlstr="Select Fk_FriendsType_Id From [Fk_FriendsType] Where Fk_FriendsType_Id=" & Id
	Rs.Open Sqlstr,Conn,1,3
	If Not Rs.Eof Then
		Application.Lock()
		Rs.Delete()
		Application.UnLock()
		Response.Write("ok")
	Else
		Response.Write("要删除的友情链接类型不存在！")
	End If
	Rs.Close
End Sub

Call FKFun.PageEnd()
%>
