<%
'--------------------------------------
'Power By 580Web @2010-2014 f02
'URL:http://www.580Web.Cn/
'EMail:wsok85@qq.com
'QQ:253819801
'版权所有 未经允许不得去除本版权信息
'--------------------------------------

'==============================
'函 数 名：getPageCode
'作    用：获取页码
'==============================
Function getPageCode(gType,gModuleUrl,gPageNow,gPageCount,gPageSize,gRecordCount)
	gType=Clng(gType)
	Select Case gType
		Case 0
			getPageCode=getShowPageCode0(gModuleUrl,gPageNow,gPageCount,gPageSize,gRecordCount)
		Case 1
			getPageCode=getShowPageCode1(gModuleUrl,gPageNow,gPageCount,gPageSize,gRecordCount)
	End Select
End Function

'==============================
'函 数 名：getShowPageCode0
'作    用：页码输出_中文
'==============================
Function getShowPageCode0(gModuleUrl,gPageNow,gPageCount,gPageSize,gRecordCount)
	Dim gPageUrl
	getShowPageCode0=""
	If gPageNow>1 Then
		gPageUrl=Replace(gModuleUrl,"Index_{mypage}"&FullHtmlSuffix,"")
		gPageUrl=Replace(gPageUrl,"&page={mypage}","")
		gPageUrl=Replace(gPageUrl,"&Page={mypage}","")
		getShowPageCode0=getShowPageCode0&"<a href="""&gPageUrl&""" title=""第一页"">第一页</a>"
		getShowPageCode0=getShowPageCode0&"&nbsp;"
		If gPageNow=2 Then
			gPageUrl=Replace(gModuleUrl,"Index_{mypage}"&FullHtmlSuffix,"")
			gPageUrl=Replace(gPageUrl,"&page={mypage}","")
			gPageUrl=Replace(gPageUrl,"&Page={mypage}","")
		Else
			gPageUrl=Replace(gModuleUrl,"{mypage}",(gPageNow-1))
		End If
		getShowPageCode0=getShowPageCode0&"<a href="""&gPageUrl&""" title=""上一页"">上一页</a>"
	Else
		getShowPageCode0=getShowPageCode0&"第一页"
		getShowPageCode0=getShowPageCode0&"&nbsp;"
		getShowPageCode0=getShowPageCode0&"上一页"
	End If
	getShowPageCode0=getShowPageCode0&"&nbsp;"
	If gPageCount>gPageNow Then
		gPageUrl=Replace(gModuleUrl,"{mypage}",(gPageNow+1))
		getShowPageCode0=getShowPageCode0&"<a href="""&gPageUrl&""" title=""下一页"">下一页</a>"
		getShowPageCode0=getShowPageCode0&"&nbsp;"
		gPageUrl=Replace(gModuleUrl,"{mypage}",gPageCount)
		getShowPageCode0=getShowPageCode0&"<a href="""&gPageUrl&""" title=""尾页"">尾页</a>"
	Else
		getShowPageCode0=getShowPageCode0&"下一页"
		getShowPageCode0=getShowPageCode0&"&nbsp;"
		getShowPageCode0=getShowPageCode0&"尾页"
	End If
	getShowPageCode0=getShowPageCode0&"&nbsp;"&gPageSize&"条/页&nbsp;共"&gPageCount&"页/"&gRecordCount&"条&nbsp;当前第"&gPageNow&"页&nbsp;"
	If gPageCount>1 Then
		getShowPageCode0=getShowPageCode0&"<select name=""Change_Page"" id=""Change_Page"" onChange=""window.location.href=this.options[this.selectedIndex].value"">"
		For i=1 To gPageCount
			If i=1 Then
				gPageUrl=Replace(gModuleUrl,"Index_{mypage}"&FullHtmlSuffix,"")
				gPageUrl=Replace(gPageUrl,"&page={mypage}","")
			Else
				gPageUrl=Replace(gModuleUrl,"{mypage}",i)
			End If
			If i=gPageNow Then
				getShowPageCode0=getShowPageCode0&"<option value="""&gPageUrl&""" selected=""selected"">第"&i&"页</option>"
			Else
				getShowPageCode0=getShowPageCode0&"<option value="""&gPageUrl&""">第"&i&"页</option>"
			End If
		Next
		getShowPageCode0=getShowPageCode0&"</select>"
	End If
End Function

'==============================
'函 数 名：getShowPageCode1
'作    用：页码输出_英文
'==============================
Function getShowPageCode1(gModuleUrl,gPageNow,gPageCount,gPageSize,gRecordCount)
	Dim gPageUrl
	Dim i_Start,i_End,i_Page
	i_Start=0
	i_End=0
	If gPageNow=1 Then
		getShowPageCode1="Previous Page"
	Else
		gPageUrl=Replace(gModuleUrl,"Index_{mypage}"&FullHtmlSuffix,"")
		gPageUrl=Replace(gPageUrl,"&page={mypage}","")
		gPageUrl=Replace(gPageUrl,"&Page={mypage}","")
		getShowPageCode1="<a href="""&gPageUrl&""" title=""Previous Page"">Previous Page</a>"
	End If
	If gPageCount<=10 Then
		i_Start=1
		i_End=gPageCount
	ElseIf gPageNow<=5 Then
		i_Start=1
		i_End=10
	ElseIf (gPageCount-gPageNow)<=5 Then
		i_Start=gPageCount-10
		i_End=gPageCount
	ElseIf gPageCount=gPageNow Then
		i_Start=gPageCount-10
		i_End=10
	Else
		i_Start=gPageNow-4
		i_End=gPageNow+5
	End If
	For i_Page=i_Start To i_End
		If i_Page=gPageNow Then
			getShowPageCode1=getShowPageCode1&" ["&i_Page&"] "
		Else
			If i_Page=1 Then
				gPageUrl=Replace(gModuleUrl,"Index_{mypage}"&FullHtmlSuffix,"")
				gPageUrl=Replace(gPageUrl,"&page={mypage}","")
				gPageUrl=Replace(gPageUrl,"&Page={mypage}","")
			Else
				gPageUrl=Replace(gModuleUrl,"{mypage}",i_Page)
			End If
			getShowPageCode1=getShowPageCode1&" <a href="""&gPageUrl&""" title="""&i_Page&""">"&i_Page&"</a> "
		End If
	Next
	If gPageNow<gPageCount Then
		gPageUrl=Replace(gModuleUrl,"{mypage}",(gPageNow+1))
		getShowPageCode1=getShowPageCode1&" <a href="""&gPageUrl&""" title=""Next Page"">Next Page</a> "
		gPageUrl=Replace(gModuleUrl,"{mypage}",gPageCount)
		getShowPageCode1=getShowPageCode1&" <a href="""&gPageUrl&""">&gt;&gt;|</a> "
	Else
		getShowPageCode1=getShowPageCode1&" Next Page "
	End If
End Function
%>
