<!--#include file="../../Inc/Cls_Main.Asp"-->
<!--#include file="../inc/Cls_Admin.Asp"-->
<!--#include file="../inc/Cls_MapPath.Asp"-->
<!--#include file="../Admin_Check.Asp"-->
<%
Dim CmsAdmin, ToUrl
ToUrl = CmsFun.LoadToUrl()
'=============================================================================
Set CmsAdmin = New Cls_Admin
CmsAdmin.SetAdminTitle = CmsSiteName
CmsAdmin.SetBodyCssName = "mainbody"
CmsAdmin.SetAdminPath = CmsAdminMapPath
CmsAdmin.LoadHead()
'=============================================================================
Dim Action
'=============================================================================
Action = Easp.Get("action")
Select Case Action
    Case "pageload"
        Call PageLoad()
    Case "delall"
        Call DelAll()
    Case Else
        Call PageLoad()
End Select
CmsAdmin.LoadFooter()
Set CmsAdmin = Nothing

Sub PageLoad()
    ChkSysAdminLevel "sys_free", "show"
    '=====================================================================
    Dim Keywords
    Keywords = Easp.Get("Keywords:s")
%>
<div class="navigation">控制面板 &gt; 自定义标签管理</div>
<div class="tools_box">
  <div class="tools_bar">
    <div class="search_box">
      <form id="searchType" action="" method="get">
        <input name="Keywords" type="text" id="Keywords" class="txtInput w200" autocomplete="off" value="<%=Keywords%>" />
        <input type="submit" value="搜索" class="btnSearch" />
      </form>
    </div>
    <ul>
      <li><a href="Admin.Tag.Add.Asp" class="tools_btn"><span><b class="add">添加标签</b></span></a></li>
      <li><a href="javascript:void(0);" onclick="checkAll(this);" class="tools_btn"><span><b class="all">全选</b></span></a></li>
      <li><a href="javascript:void(0);" onclick="return ExePostBack('确定要批量删除吗？','myform','?action=delall');" class="tools_btn"><span><b class="delete">批量删除</b></span></a></li>
      <li><a href="Admin.Tag.List.Asp" class="tools_btn"><span><b class="refresh">刷新列表</b></span></a></li>
    </ul>
  </div>
</div>
<form id="myform" action="?action=delall" method="post">
  <table width="100%" border="0" cellspacing="0" cellpadding="0" class="msgtable">
    <tr>
      <th width="5%">选择</th>
      <th width="30%" align="left">标签说明</th>
      <th width="45%" align="left">调用代码</th>
      <th width="10%">添加时间</th>
      <th width="10%">操作</th>
    </tr>
    <%
    Dim ShowPage, oRs, PageNum, ArrayList, i, oSQL, TempWhere
    ShowPage = ""
    PageNum = 20
    '============================ search
    TempWhere = " 1 = 1 "
    If Not Easp.IsN(Keywords) Then
        TempWhere = TempWhere & " And Desc Like '%"& Keywords &"%' "
    End If
    '============================ page
    Easp.db.PageSize = PageNum
    Easp.db.SetPager "default", "<span class=""disableds"">总记录数:{recordcount},每页:{pagesize},页次:{pageindex}/{pagecount}</span> {first}{prev}{list}{next}{last}{jump}", Array("first:首　页", "last:尾　页", "prev:上一页", "next:下一页", "list:*")
    Set oRs = Easp.db.GPR("0", Array(TablePrefix & "FreeTag:Id,Info,Title,AddTime", TempWhere, " id Desc ", " id "))
    If Easp.IsN(oRs) Then
        Easp.C(oRs)
    Else
        ShowPage = Easp.db.GetPager("default")
        ArrayList = oRs.GetRows(PageNum)
    End If
    Easp.C oRs
    If IsArray(ArrayList) Then
        For i = 0 To UBound(ArrayList, 2)
    %>
    <tr align="center">
      <td><input type="checkbox" name="chkId" value="<%=ArrayList(0,i)%>" /></td>
      <td align="left"><%=ArrayList(1,i)%></td>
      <td align="left"><input type="text" class="txtInput2 w350" value="{ZjjCmsTag:<%=ArrayList(2,i)%>}" /></td>
      <td><%=CmsFun.TimeToString(ArrayList(3,i),"yyyy-mm-dd")%></td>
      <td><a href="Admin.Tag.Edit.Asp?id=<%=ArrayList(0,i)%>">编辑</a></td>
    </tr>
    <%
        Next
    End If
    %>
  </table>
  <div class="line15"> </div>
  <div class="page_box">
    <div class="flickr right"><%=ShowPage%></div>
  </div>
</form>
<%
End Sub

Sub DelAll()
    ChkSysAdminLevel "sys_free", "del"
    '=====================================================================
    Dim chkId, ResultVal
    chkId = Easp.Post("chkId:s")
    If Easp.IsN(chkId) Then
        CmsAdmin.JscriptMsg "对不起，请选中您要操作的记录！", "back", "Error", "null"
    Else
        ResultVal = Easp.db.DR(TablePrefix & "FreeTag", "Id:" & chkId)
        If ResultVal <> 0 Then
            CmsAdmin.JscriptMsg "批量删除成功！", ToUrl, "Success", "null"
        End If
    End If
End Sub
%>